# 1.3 Using Arithmetic Functions

In addition to writing formulas that use constants, cell references, and operands, formulas may also include ***functions***. Functions are predefined formulas that perform specific calculations. When a function is used in a formula, the user only needs to supply the function’s inputs (*arguments*) and the result of the function’s calculation will be used when the computer evaluates the formula. This section will present several different commonly used functions: SUM, AVERAGE, COUNT, MIN and MAX. Functions that can be used to perform more sophisticated analyses, such as ROUND, SUMIF, and COUNTIF, will also be introduced.

## Functions with only range Arguments

###### The Sum Function

The most simple and commonly used function is the ***SUM*** function, which is designed to add a list of values. These values may be input directly into the formula as constants, references to cells, or ranges of cells containing arithmetic values. The syntax of the SUM function is as follows:

**=SUM(number1**, number2, number3…**)**

All Excel functions share a common syntactical structure: a ***function name*** followed by an open parenthesis, then a list of ***arguments*** -inputs needed by the function in a specific order separated by commas, and finally a closing parenthesis. Some function arguments are required and some are optional. The required arguments will be written in **bold** text and the optional arguments will be written in normal text. Each function has a unique function name and specific list of arguments. In addition to a function’s syntax, each function has a set of rules that must be followed so that the function returns the expected result.

An example of a SUM function that adds the values in the cells A5 to A100 is **=SUM(A5:A100)**. Functions can be used by themselves or in combination with other operands as part of a larger formula for example **=SUM(A2:A7)/B8-SUM(5,7,B35, A8:C8).** Notice that in this example the formula contains two SUM functions as well as the division and subtraction operators. The first SUM function will add all of the values in cells A2, A3, A4, A5, A6 and A7. The second SUM function will add the constant values 7 and 5, the value in cell B35 and the values in cells A8, B8 and C8. If these cells to not contain a numeric values (are blank, contain text or Boolean values) the function will ignore them.

The SUM function is a useful both for saving time and making a spreadsheet robust to changes. The formula **=A1+A2+A3** accomplishes the same task as the formula **=SUM(A1:A3)**, so why bother to use the SUM function? First, the SUM function can save time. Consider how tedious it would be to sum the cells A1 through A100 using only the additional operator (+). It is much more efficient to write **=SUM(A1:A100)** than it is to type out the corresponding addition. Also consider if a row were to be inserted in between A1 and A2. If the inserted value needs to be included in the summation, the formula would need to be modified as follows: **=A1+A2+A3+A4**. When inserting rows and/or columns into a worksheet, Excel will automatically update cell references within formulas. If the formula =SUM(A1:A3) is used, since the old A3 becomes A4, the range would update to **=SUM(A1:A4)**,automatically including the inserted row.

###### inserting functions into a formula

There are several different methods available for entering functions in a formula.When writing a formula, at the point where a function is to be inserted, use one of the following techniques:

* **Manually type** in the function name, open parenthesis, and each of the arguments as required. Once the function name and parenthesis has been typed, the computer will display the syntax of the function directly below the active cell. When entering cell references as arguments either directly type the cell reference directly into the formula or use the mouse to click on the desired cell or range of cells. Clicking on the cells while typing a formula will automatically incorporate the reference as part of the formula. This method is quick but requires the user to know the exact function name.
* Use the **AutoSum ∑ button** for the SUM, AVERAGE, MIN, MAX or COUNT functions only, located both on the Home and Formulas tab. When using this feature, Excel will typically “sense” what range of numbers is to be added, averaged, etc. This range can be modified by the user.
*  Use the ***Insert Function Tool*** to access all available functions in Excel by clicking on the  button next to the Formula Bar or on the Formulas Ribbon. As seen in *Figure 1,* a dialog box will appear listing function names and categories. To find a specific function, use the search feature or select from one of the categories and click on the name of the desired function. This will open another dialog box (*Figure 2*) containing the function name and input areas for each of the function’s arguments.



Figure 1

Figure 2

###### Functions with one argument type:

The functions AVERAGE, MIN, MAX, and COUNT are similar in syntax to the SUM function in that their arguments are just a list of numbers. The syntax of these functions are as follows:

|  |
| --- |
| **Function-name(arguments)**  ***Function Descriptions*****SUM** (**number1**, number2 ….) Calculates the sum of a list of values**AVERAGE**(**number1**, number2..) Calculates the average value of a list**MIN**(**number1**, number2 ….) Returns the minimum value in a list**MAX** (**number1**, number2 ….) Returns the maximum value in a list**COUNT**(**number1**, number2 ….) Determines the number of values in a list |

The SUM, MIN, MAX, AVERAGE and COUNT functions are simple in that they only contain one type of argument – a list of values. Unlike other functions that will be presented later, the order of the list does not matter. The formula **=MIN(B2,B5,7)** will return an identical result as the formula **=MIN(7,B2,B5)**. Each argument can be a constant, a single cell reference or even a range of cells. Examples of ranges of cells are:

* **B2:B7 -** a range down a column
* **B2:Z2 -** a range along a row
* **B2:Z7 -** a 2-diminsional range including all cells within – B2, B3, B4, …B7, C2, C3, C4.. C7… all the way to Z7

To see how different formulas can be combined, consider the formula **=MAX(A1:A100)/SUM(B2:X2,50,A99).** The first operand will be the result of the MAX function. In this case, the MAX function will find the highest value in the column range starting in row 1 and going through row 100 of column A. The result of this MAX function will then be divided by the result of the SUM function from the denominator. The SUM function contains three elements – a range along row 2 from columns B through X, the constant value 50, and the value contained in cell A9.

Detailed descriptions of each function including their syntax, rules of use, and examples can be found using the Help feature of Excel.

###### A function’s rules & specifications:

Consider the worksheet in Figure 3. This worksheet lists the service ratings for several different phone providers by region (East, Midwest, South and West). Each provider is given a rating on a 100 point scale, where 100 is a perfect score. In cell C10 the formula **=AVERAGE(C5:C8)** calculates the average of the values in cell C5,C6,C7 and C8. This formula is copied across the row into cells D10:G10.

Figure 3

Notice cell D18 is blank. Should the average be calculated as 90+80+70+0 divided by 4 or 90+80+70 divided by 3? There is no one right answer to the question as to whether or not the Midwest Service score for Spruce be counted as a zero or ignored, it will depend on how the values are being used. The designers of Excel decided between these two possibilities in the rules of the AVERAGE function.

The rules of the AVERAGE Excel function state that ***blank cells are ignored***. When Excel evaluates the formula **=AVERAGE(D5:D8)** it adds 90+80+70 and divides the result by 3. A zero would need to be placed in cell D8 to count the blank cell as part of the average.

The rules for SUM, COUNT, MIN, and MAX are similar. If a range includes cells that do not contain arithmetic values, but contain labels or are blank, the function will ignore them. An attempt to count the number of phone providers in the survey might be to use the formula **=COUNT(A5:A8)**. However, this formula will result in the value 0 as cells A5 through A8 contain text, not numerical values. Instead, use the formula **=COUNT(G5:G8),** which will return the value 4.

Why do we need to observe these rules so closely? A computer will take the inputs of a function and apply a list of well defined instructions to obtain the results. This defined step-by-step method determining a function’s results is known as an ***algorithm.*** All of the functions in Excel have an underlying algorithm which the programmer has coded into the software. This ensures that every time a specific function is used a uniform methodology is applied; an AVERAGE function can’t sometimes count blank cells and sometimes not.

###### A Few More Tips to Using Functions:

As mentioned previously, functions can be used by themselves or in combination with other operands as part of a larger formula for example: **=SUM(A2:A7)/Count(A1:E1)\*5.** It is also possible to ***nest*** functions inside of each other. For example, the formula =**MAX(Sum(1,5,10),25)** will first calculate a value for the SUM function (16) and then use the result as an argument of the MAX function (comparing 16 to 25). The final value will be 25. Excel will allow up to 7 levels of nesting.

|  |
| --- |
| ***What Not to do:*** A frequent mistake made when inputting data into a spreadsheet is to input a number as a text label. *Figure* 4 illustrates how Excel shows the difference between numbers input as text (the characters 2 and 5) and numbers input as numeric values (the number 25). A number can be input as text if a quotation mark (single or double) is entered first (*e.g.* ’25’) or if the value is copied from another software application as text and pasted into Excel. Figure 4Excel does not consistently recognize labels as numerical values, so this can create problems. For example, the formula **=B1+B2** will result in the value 50 but the formula **=SUM(B1:B2)** will result in the value 25. Unless modified, Excel formats numerical values as right justified and text labels as left justified making it easy to spot this problem. Often Excel will also place an error alert, a small green triangle, in the upper left hand corner of a cell containing a number input as text. If you have created a spreadsheet with a column of numbers that do not add up properly, frequently the mistake is that one or more of the cells contain a label, instead of a value. Be very careful of data copied from other sources, especially since the resulting spreadsheet may right justify text making it difficult to detect this error. |

###### A Simple Problem:

In the introduction an outline was presented for a general problem solving technique which incorporated the overall planning and implementation of a solution. Recall that step 4 of the technique was translating a problem into mathematical formulas and then encoding these formulas into the proper syntax.

One method of translating a problem and encoding it to a spreadsheet is to use the following 3-step process:

* **Step 1:** Determine what the problem is asking and ***how you would solve it without using a computer***. This may be an algebraic expression, counting, averaging, making a logical decision, finding something from a list, etc.
* **Step2:** ***Translate your solution into Excel syntax*** using the necessary values, cell references, operands, and functions.
* **Step 3:** Determine if this formula is to be copied and ***include absolute cell referencing only as needed***.

For very simple problems these steps can be gone through quickly, in more complex problems writing out each successive step will aid in developing a correct solution.

In *Figure* 5 is a similar worksheet to the one seen previously. Now answer the following questions using this approach to write the appropriate Excel formulas.

Figure 5

**Question #1:** Write a formula in cell G5 to total the service rating points for BT&T. Assume this formula will be copied down the column to total the ratings for each of the other service providers.

* **Step 1 – What does the problem ask to be calculated?** The total of the ratings for BT&T is the sum of the values in cells C5 through F5. Algebraically this can be expressed as =81+90+99+86.
* **Step 2 – Translate into Excel syntax.** In Excel syntax this can be either **=C5+D5+E5+F5** or **=SUM(C5:F5)**. In this case, either formula is correct. However, the SUM function is quicker and easier to use.
* **Step 3 – Is the formula =SUM(C5:F5)** **being copied?** Yes, this formula will be copied down the column to find the corresponding value for each of the other phone providers. When G5 is copied to G6 and beyond, does the cell reference C5 in the formula change relative to the new position? Does F5 change relative to the new position? Yes, both of these terms will change relatively, the new formula in cell G6 will be **=SUM(D6:F6).** No absolute referencing is required.

|  |
| --- |
| ***What Not to do:***Often inexperienced spreadsheet users will write the solution as follows:* =SUM(C5,D5,E5,F5) while this is valid it is ***not*** ***recommended*** as a continuous range is more simply represented by typing C5:F5. Non-continuous cells and ranges should be listed out explicitly (=SUM(C5,Z125,A3).
* =SUM(C5+D5+E5+F5) again while this is valid it is ***not*** ***recommended*** as it nests the addition within the function The computer will first add these values reducing the formula to =SUM(345) and then to just 345. The SUM function is superfluous since the values are already added.
 |

**Question #2:** Write an Excel formula in cell H5, which can be copied down the column, to calculate the total points received by BT&T as a percentage of the total possible points.

* The total points received by BT&T are 345 and the total possible points are 400. The percentage would then be 345/400.
* The total of the points received by BT&T is listed in cell G5 and the total possible points are listed in cell G3. The arithmetic expression 345/400 can then be translated into the formula **=G5/G3**. No function is required, just a division operation.
* This formula is being copied down the column. If it is copied relatively, the resulting formula in cell H6 will be **=G6/G4**. The numerator G6 is correct; G6 is the corresponding total points received by Blue Phone. However, denominator is incorrect. The total possible points should remain 400, so the cell G3 should remain the same. Therefore, the ***row*** of the denominator cell reference should be held absolute. The final formula will be **=G5/G$3**.

|  |
| --- |
| ***What Not to do:***Why not write the formula like this =$G5/$G$3 – adding in absolute cell references in front of the column addresses? When copying a formula down a column only, the column letter never changes. Thus placing a $ in front of each column address would be unnecessary. ***To keep things clear and simple only add a absolute ($) cell reference if absolutely necessary.*** Compare =$G5/$G$3 vs. =G5/G$3. Even for this simple formula the latter expression is easier to read. If this formula is only being copied down the column, it’s very hard to see what rows are relative and absolute in the first formula, whereas it’s extremely clear what is relative and absolute in the second formula. |

**Question #3:** Write an Excel formula in cell C11 (not shown), that can be copied across the row, to determine the poorest service rating given by the Eastern region.

Go through the 3-step process. The answer you should obtain is: **=MIN(C5:C8).**

When copied into cell D11 will this formula result in the value 70 or the value 0? Since the MIN function ignores blank cells (D8) the minimum rating would be 70.

**Question #4:** Write a formula in cell C12 (not shown), which can be copied across the row, to calculate the number of phone providers surveyed in this region.

* Determining the number of providers in the East region involves counting the number of non-blank cells listed in column C of the worksheet.
* Counting the number of non-blank cells can be accomplished using the COUNT function. In Excel syntax this corresponds to the formula **=COUNT(C5:C8)**.
* When copied across the range, the reference C5:C8 will change relatively, so no absolute cell referencing is needed.

**Question #5:** Will the formula =AVERAGE(C5:C8) ***always*** give you the same result as =SUM(C5:C8)/4?

Remember, the algorithm for the AVERAGE function ignores cells that are blank or contain labels. So if any cell in the range C5:C8 contained a non-numeric value, while the sum of the values would not change the denominator 4 would. The AVERAGE function will divide the sum by the number of cells containing numeric values. Thus the formulas will not result in the same value. An equivalent formula to **=AVERAGE(C5:C8)** would be =SUM(B2:B6)/COUNT(B2:B6).

## The Round Function

Again consider the ratings spreadsheet as seen in *Figure* 6. If the values in cells C5:C8 are averaged, the precise value of 68.75 will result. Shown in cell C10 is the result of the formula **=AVERAGE(C5:C8)** displayed with zero decimal places, 69. What if you are instructed to estimate the number of households which found this provider acceptable by multiplying the average rating rounded to the nearest whole number by 1,000? If the formula **=C10\*1000** is used the resulting value will be 68,750 not 69000. How can the precise value in cell C10 be rounded, not just the display?

Figure 6

###### The round function syntax:

The ROUND function can be used to round a specific value to a specified number of decimal places. The syntax of the ROUND function is:

**=ROUND(number,num\_digits)**

The Round function is different than the functions seen thus far in that it has more than one type of argument, each with a different meaning. In addition the order of its arguments will affect the value calculated by the function. The ROUND function’s arguments are as follows:

* **Number:** The first argument is a single value that can be a constant, a cell reference where the cell contains a numerical value, or a nested formula that results in a single number value.
* **Num\_digits:** The second argument is the specified number of decimal places. For example, a value of 0 for the second argument tells the computer to round to the nearest whole number. A value of 1 for the second argument tells the computer to round to the nearest tenth (0.1, 0.2 ..). A value of -2 for the second argument tells the computer to round to the nearest hundred (100,200…).

The ROUND function algorithm rounds down all values of less than half the range, and rounds up values from half the range and above. For example **= ROUND(1.49,0)** will result in the value 1 while the formula **= ROUND(1.50,0)** will result in the value 2. As with all other functions, the ROUND function can be used alone, as part of larger formulas, or nested inside of other functions.

So to answer the original question of how to take the average rating score rounded to the nearest whole number and then multiply by 1000, write the formula **=ROUND(C10,0).** Unlike changing the display of a cell, this function will actually convert that number’s *precision*. There are many other similar functions in Excel such as **INT** and **ROUNDUP** that also alter the precision of a value. Use the Function Wizard to explore some of these other functions.

###### Some Simple examples of using the round function:

Consider a spreadsheet with cell A1 containing the numeric value 78.43, and cell A2 containing the numeric value 78.686788. Here are some additional examples of formulas using the ROUND function:

* The formula **=ROUND(A2,2)** results in the value 78.69. The first argument tells the computer to take the value in cell A2, which is 78.686788. The second argument indicates that this value is to be rounded to the nearest hundredth.
* The formula **=ROUND(A2,0)** results in the value 79
* The formula **=ROUND(A2,-1)+5** results in the value 85. First the ROUND function will be evaluated, resulting in the value 80. Then the number 5 will be added, resulting in 85. Notice that rounding to the -1 decimal place is the same as rounding to the nearest ten.
* The formula **=ROUND(0.1+Min(A1, A2),0)** results in the value 79. The computer will first evaluate the MIN function, resulting in 78.43. Adding 0.1 to 78.43 is 78.53. Rounding this to zero decimal places results in 79.

###### Rounding multiple values:

How can 69.98 rounded to the nearest tenth be added to 3.01 rounded to the nearest tenth?

Does the formula **=ROUND(69.98,3.01,1)** correctly implement this calculation? No, Excel will alert the user that there are too many arguments in this function as it would interpret 69.98 as the value to be rounded, 3.01 as the number of decimal places to round to, and not know what to do with the value 1.

Does the formula **=ROUND(69.98+3.01,1)** correctly implement this calculation? No. This formula rounds the values after they have been added. This might change the overall value of the solution. Consider if the values were 1.36 and 1.06. 1.36 rounds to 1.4 and 1.06 rounds to 1.1. Adding them together results in the value 2.5. Yet this formula would add 1.36+1.05 resulting in the value 2.41. Rounded to this to the nearest tenth would result in 2.4 and not 2.5. This implementation would be correct if the problem asked for the rounded sum of these values as opposed to the sum of each rounded value.

The correct answer requires both values to be rounded before they are added. Translating this into Excel syntax results in the formula **=ROUND(69.98,1)+ROUND(3.01,1)**.

Since the functions SUM, COUNT, AVERAGE, MIN, and MAX all work with any number of arguments, a common mistake is to believe that functions like the ROUND function work similarly. It is important to remember that Excel uses the comma (,) to delimit different arguments and in functions like the ROUND function, Excel expects a specific number of arguments in a specific order. Inserting too many arguments or changing the order of the arguments can result in either an error message or an incorrect value. Remember that Excel can’t “infer” what we want it to do if we don’t write our formulas obeying Excel’s syntax and rules.

## The Countif Function

Thus far functions have been used to answer questions like “What is the average grade?” or “What is the maximum grade?” But how can we answer the question “How many phone providers are there on a type B network?” To answer this question we will need to look at the spreadsheet in *Figure* 7 and count the number of cells containing the letter B in the range B5:B8.

The fact that something is being counted may imply that a COUNT function can be used. However, the COUNT function can only count the number of numerical values in a list, which is not what is needed here. There is even a COUNTA function that can count the number of numerical and text values in a list, but this still does not capture the process we go through to count only type B network providers. What we really need to do is find a way to count items in a list that *meet a specified criterion*.

Figure 7

###### The countif function syntax:

The COUNTIF Function is designed to count the number of items in a range that meet a user specified criterion. The syntax of the function is as follows:

**=COUNTIF(range,criteria)**

This function has two arguments: a continuous cell range and a criterion. The COUNTIF function will only work as intended if the correct number of arguments are entered in the correct order. The COUNTIF function is further differentiated from the COUNT function in that it works equally well with text labels as with values so that it will be possible to count the number of B’s in a range of cells. The valid methods of specifying a criterion in this function include but are not limited to the following:

|  |  |
| --- | --- |
| **Criteria Type:** | **Example:** |
| **Using a specific text value**  | **=COUNTIF(B2:C4,“xyz”)** will find all instances of the text string xyz (caps or small letters) in the continuous range B2 through C4. |
| **Using a specific numerical value**  | **=COUNTIF(B2:B10,0)** will find all instances of the value zero in the continuous column range from B2 to B10. |
| **Using a cell reference** | **=COUNTIF(B2:B10,B2)** will find all instances of the value found in cell B2 in the continuous range B2 to B10. Note that cell B2 may contain text, a numerical value or a Boolean value. |

|  |  |
| --- | --- |
| **Using a relational expression** **(>,<, >=,<=,<>)** | **=COUNTIF(B2:B10,“>0”)** will find all instances of values that are greater than zero in the continuous range B2 to B10. Notice the special syntax here. It is unusual to use quotes in numerical expressions. The COUNTIF function is one of the few exceptions in Excel where quotes are used except to indicate text. |
| **Using a specific Boolean value**  | **=COUNTIF(B2:F2,TRUE)** will find all instances of the value TRUE in the continuous range from B2 to F2. Notice that TRUE does not have quotes since it is a Boolean value and not a label. (Boolean values will be introduced in the next chapter.) |

This function can only accommodate a single ***continuous range*** argument (one or two dimensional range). A list of cell references and/or non-continuous ranges cannot be interpreted by this function since the first time it encounters the comma delimiter it assumes a criterion will follow, not additional ranges. =COUNTIF(B2:B10,C2:C10, “x”) has no meaning since the computer would assume that C2:C10 is a criterion that it is unable to evaluate.

Remember, Excel treats capital and small letters as the same. So specifying “X” is the same as specifying “x”. This is not the case for all software packages.

###### Using the Countif function:

Each of the examples below further illustrates the different types of criteria that a COUNTIF function can use. Using *Figure* 8 and the 3-step process, solve the following problems.

Figure 8

**Question #1:** Write an Excel formula to determine the number of rating scores for all providers and all regions that received an unacceptable rating. The minimum acceptable rating is 80. What value will result?

* The question asks for the number of scores below 80 for all providers and regions. To answer this question, count the number of scores in the range C5:F8 that are less than 80.
* The COUNTIF function can be used to count the number of cells that meet a criterion. The first argument is the range, which in this case is C5:F8. The criterion is less than 80. Hence, the formula would be **=COUNTIF(C5:F8, “<80”).** The resulting value is 5, since five of the ratings listed are below 80. Note that this function also ignores cells that are blank.
* Since the formula is not copied, all cell references should be left as relative.

Should a cell reference be used instead of the value 80 so that if the acceptable score changes so would the result of the function? In general it is always better to reference a value, so if it changes it needs to be modified in just one place. However, ***the COUNTIF function algorithm is not setup to recognize a cell reference together with a relational operator***. It will accept a simple cell reference (E1) or a relational operator (“<80”) but not both (“<E1”) unless additional special characters are added.

**Question #2:** Write an Excel formula in cell B12 (not shown) to determine the number of networks of either type B or type Z.

* To solve this problem without a computer look for the data that specifies each provider’s network type (column B) and then count the number that meets the criteria, which is either a B or Z.
* The COUNTIF function can only count the number of entries that meet one single criterion, not two. However, the number of B’s can first be counted and then added to the number of Z’s: **=COUNTIF(B3:B7,“B”)+COUNTIF(B3:B7,“Z”)**
* Since this formula is not copied, no absolute cell referencing is required**.**

###### A more complex example:

Consider the example in *Figure* 9 which contains a slightly modified version of the rating spreadsheet including a Summary by network type in rows 11 through 13.

Figure 9

What formula will be needed in cell B11 to determine the number of networks of type H? How can this formula be written so that it can be copied down the column to automatically calculate this value for type B networks and type Z networks? Solve using our 3-step process as follows:

* To determine the number of type H networks, count the number of occurrences of “H” in the Network Type column in the range B5:B8.
* A COUNTIF function counts the number of values that meet a criterion. The range of cells the criterion will be compared to is B5:B8 and the criterion is “H”, so the corresponding formula will be =COUNTIF(B5:B8,“H”).
* Consider copying the formula down the column to cell B12. The formula used in cell B12 should count the number of type B networks. If the formula in cell B11, =COUNTIF(B5:B8,“H”), is copied relatively the new formula will be =COUNTIF(B6:B9,“H”).
	+ Notice that the range argument will change by one cell; the new range excludes the data in cell B5 and includes the blank cell in row 9. This range should remain unchanged by adding absolute cell referencing to the rows. Now the resulting formula would be =COUNTIF(B$5:B$8,“H”).
	+ Although the range is now correct, this formula as written still *adds the number of type H networks instead of the number of type B networks*. One solution is to use a cell reference to specify the criteria instead of placing an ‘H’ directly into the formula. The reference A11 can be used, since cell A11 contains the value “H”. When the formula **=COUNTIF(B$5:B$8,A11)** is copied down, the reference will change to A12, corresponding to the value “B” as desired.

## The Sumif Function

Again consider the worksheet in Figure 9. In the summary, the total rating points for each network type and region appear in cells C11:G13. Calculating these values using the tools we’ve learned thus far would require writing a different formula for each row. This solution would be tedious and would require updating if the network types were to change in the future. The process used to calculate the total for each cell is essentially the same - in each region the rating points are added for only companies that have the corresponding network type. Ideally, this process should be automated to sum values that meet a specific criterion.

###### The sumif function syntax:

 The SUMIF Function is designed to add all values in a range that meet a specified criterion. Its syntax is as follows:

**=SUMIF(criteria\_range,criteria,**sum\_range**)**

The SUMIF function has three arguments:

1. The ***criteria range***is the range of values to be compared against the criterion.
2. The ***criteria*** argument is the specific value (text, numerical, Boolean) or relational expression to compare each value in the criteria range to.
3. The ***sum range*** is the corresponding range of cells to sum if the criterion has been met. If this range is the same as the criteria range then it may be omitted.

This function works almost identically to the COUNTIF function in that its ranges must be continuous and the criteria may be a value, cell reference, or relational expression. The same syntactical rules apply for specifying criteria.

###### Using the SUMif function:

Before tackling the question at the beginning of this section, consider some simple examples of the SUMIF function using the spreadsheet in Figure 10

Figure 10

**Question #1:** Write an Excel formula to determine the total points awarded to all type H network providers from all regions combined.

* First look at column B and decide which providers have a type H network, and then add the total points of those providers only. Column G lists the total points that each provider received.
* The manual step-by-step process of solving this problem involved adding values if a specific criterion was met. This can be accomplished using a SUMIF function.
* The first argument of the SUMIF function is the criteria\_range. In this case, column B (B5: B8) contains the value to be compared to the criterion, the Network type.
* The second argument is the criteria, in this case whether or not the network type of the provider is type H. In Excel syntax this is written as an “H”. Note that quotations marks are required as the criterion is text.
* The third argument is the sum\_range. In this case add the values in column G in the corresponding rows 5 through 9. The resulting formula would be:

**=SUMIF(B5:B8,“H”, G5:G8)**

* Since this formula is not copied, none of the cell references need to be made absolute.

**Question #2:** Ratings below 70 for a specific provider/region are considered unacceptable. Write an Excel formula in cell H5 (not shown) to calculate the total points for BT&T earned from regions with unacceptable ratings. Write the formula so that it can be copied down the column.

* To do this manually, look at each of the point totals for BT&T by region. If the region has a point value of less than 70, we would include it in the sum. In this case all regions are above 70 and the total would be 0.
* A SUMIF adds values that meet a criterion.
* The first argument is the range to compare with the criterion. In this case the range is C5:F5 which contains each region’s rating points.
* The second argument is the criteria. To find values less than 70 use the syntax “<70”. Note the unusual syntax; when using a relational operator as part of the SUMIF criteria use quotation marks around the entire expression.
* The third argument is the values to be added. Since this range is identical to the criteria range (C5:F5), this argument can be omitted (however, including it will work as well). The resulting formula is:

**=SUMIF(C5:F5,“<70”).**

* Now this formula must be copied down the column. In cell H6, the formula should be the sum of the unacceptable ratings for Blue Phone. Copying this formula down one row to cell H6, the resulting formula will be =SUMIF(C6:F6, “<70”). The range is correctly modified so there is no need for absolute references. Since the criteria for Blue Phone is the same as the criteria for BT&T, this argument also requires no additional modifications..

###### Completing the Summary Table:

Now return to our original example. How can the summary by network type be completed in cells B11:G13 (*Figure 11*)? Remember that we want to write a single Excel formula in cell C11 that will total the points for the East region for network type H and can be copied down the column and across the row to calculate the corresponding totals for types B and Z in each of the four respective regions.

Figure 11

**The Solution:**

* Again, the solution will require that values be summed together if they meet a specific criterion.
* The SUMIF function will be best suited to implement the solution. To implement this for only cell C11, write the Excel formula **=SUMIF(B5:B8,A11,C5:C8)**. The criteria range contains the phone provider’s network type in cells B5:B8, the criteria “H” will be referenced as cell A11 to make copying possible later, and the sum range will encompass the East region’s data in cells C5:C8.
* The challenge is how to make this work when copied BOTH down the column and across the row. Let’s consider each direction separately.
* What is the correct formula for cell C12 to sum the points for network type B in the East region? The formula needed will be =SUMIF(B5:B8,A12,C5:C8).
	+ Notice that the criteria\_range does not change when copied down requiring absolute cell referencing for the criteria\_range row references
	+ The criteria “H” in cell A11 changes to “B” (cell A12). So this row reference of the criteria argument must be relative.
	+ Neither does the sum\_range change when copied down, this too will require absolute row referencing
	+ The formula at this point, before considering copying across, should be modified to =SUMIF(B$5:B$8,A12,C$5:C$8).
* The formula needed in cell D11 to sum the points for network type H in the Midwest region is =SUMIF(B5:B8,A11,D5:D8).
	+ Notice the criteria\_range argument again stayed the same requiring absolute column references.
	+ When copying across from column C to column D the criteria argument stayed the same; this too will need an absolute column reference.
	+ And finally notice that the sum\_range does change from C5:C8 to D5:D8 when copyed across from cell C11 to D11. Thus the column reference should be relative for the sum\_range argument.

The final formula should then be: **=SUMIF($B$5:$B$8,$A11,C$5:C$8).**

The final formula contains a criteria range that has both an absolute column reference and absolute row reference; it never changing regardless of where it is copied. The criteria changes when copied down but remains the same when copied across, requiring an absolute column reference. The sum range, which changes when copied across but remains the same when copied down, requires an absolute row reference.

In cases where formulas are copied in two directions, mixed cell referencing is often needed for a formula to result in the correct solution. Furthermore, extra $’s not only affect the readability of the formula, but ***result in incorrect formulas***when the formula is copied. As a rule of thumb, ***only include absolute cell referencing if the formula is incorrect without it***. Minimize absolute cell referencing whenever possible.

###### Exercise 1.3–1 Functions: A Grade Book

Use the above spreadsheet answer the following questions. Assume the cells in gray have previously been filled in. Other cells may be referenced in your answers only if you have written a formula in that cell.

1. Write an Excel formula in cell G5, which can be copied down the column, to calculate the total points for Blue.
2. Write an Excel formula in cell H5, which can be copied down the column, to calculate the points received as a percentage of the total possible points.
3. Write an Excel formula in cell C10, which can be copied across the row, to calculate the highest score received on Lab1.
4. Write an Excel formula in cell C11, which can be copied across the row, to calculate the lowest score received on Lab1 .
5. Write an Excel formula in cell C12, which can be copied across the row, to calculate the number of scores recorded for this assignment/exam.
6. Write an Excel formula in cell C13, which can be copied across the row, to calculate the average score rounded to the nearest whole number.
7. Write an Excel formula in cell B14 to determine the number of honor students in this class.
8. Write an Excel formula in cell C15, which can be copied across the row, to calculate the total number of points earned by Honor students for this assignment/exam.
9. Write an Excel formula in cell C16, which can be copied across the row, to calculate the average number of points earned by Honor students for this assignment/exam.

###### Exercise 1.3-2 Functions: Rock Concert

The worksheet below is an analysis of a few popular recording artist’s concert proceeds in Columbus during a recent season. The information includes the group’s contract type (A or B), the number of people who attended their concert (Column C), the price of each concert ticket (Column D), the total number of CDs sold in Columbus (Column E), and the cost per CD (Column F). Answer the questions below, taking care to ensure that your formulas can be copied as needed.

1. Write a formula in cell G2, which can be copied down the column, to determine the Total Revenue for the Rolling Stones. Revenue = Revenue from concert + Revenue from CD sales.
2. Write a formula in cell G9 to calculate the total revenue of all groups.
3. Write a formula in cell G10 to calculate the average revenue of all groups.
4. Write a formula in cell G12 to determine the number of people who attended the concert with the highest attendance.
5. Write a formula in cell G13 to determine the total revenue of all groups rounded to the nearest $100.
6. Write a formula in cell G14 to determine average number of people attending a concert rounded to the nearest whole number.
7. Write a formula in cell G15 to determine the cost per album of the cheapest CD sold.
8. Write a formula in cell G16 to determine how many groups sold less than 20,000 CDs.
9. Write a formula in cell G17 to determine the number of groups that charged $40 for their concert tickets.
10. Write a formula in cell G18 to determine the total revenue of all groups with a Type A contract.
11. Write a formula in cell H2, which can be copied down the column, to determine this group’s revenue as a percent of the total revenue for all groups.

###### Exercise 1.3-3 Functions: Expenditures



Above is a spreadsheet with your expense and income information from January through May. Answer the following questions assuming the cells in gray are inputs already provided for you.

1. Write an Excel formula in cell C9, which can be copied across the row, to calculate the total costs for January.

2. Write an Excel formula in cell H3, which can be copied down the column, to calculate the total expenditure for rent from January through May.

3. Assuming your salary is the same each month (C11), write an Excel formula in cell C12 that can be copied across the row to calculate the amount saved in that month.

4. Write an Excel formula in cell C13, which can be copied across the row, to calculate the percent of salary that is saved in that month.

5. Write an Excel formula in cell I3, which can be ***copied both down and across*,** to calculate your January rent costs as percent of the total cost for January.

6. Write an Excel formula in cell C14 to calculate the percent change in savings from January to February.

7. Write an Excel formula in cell C15 to calculate the number of months in which the savings are greater than 37% of your salary.

8. Write an Excel formula in cell H12 to calculate the minimum amount that was saved in any month.

9. Write an Excel formula in cell C17 that can be ***copied both down and across*** to calculate the sum of costs in the rent category for January. When copied down and across it should total the costs of the corresponding category for each month.

###### Exercise 1.3-4 Functions: Chapter Review



You are the manager of a sales force for the ZAP Vacuum Company. Each month you prepare a report totaling the compensation for each salesman and comparing it to the previous month’s compensation. The spreadsheet you will fill out for this report is above and includes the following information about salesman salaries and commissions:

* Each salesman earns a monthly salary plus a commission for their sales in that month.
* The rate of commission can be found in cell B2, which has been named “comm”.

You may assume that the cells shaded gray are inputs provided for you. Answer the following questions to fill in the rest of the worksheet, using cell references wherever possible.

1. Write a formula in cell E4 to calculate the value of Arnold’s commission for April. Use the named range “comm” when writing your formula. The formula must work when copied down the column to row 9. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
2. Write a formula in cell F4, which can be copied down, to calculate the total compensation received by Arnold in April. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
3. Write a formula to be put in cell B11, which can be copied across the row, to calculate the total compensation that was paid in March. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
4. Write a formula in cell B12, which can be copied across the row, to calculate the minimum compensation that was paid to a salesman in March. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
5. Write a formula in cell B13, which can be copied across the row, to calculate the maximum compensation paid to a salesman in March. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
6. Write a formula in cell B14, which can be copied across the row, to calculate the average compensation that was paid in March. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
7. Write a formula in cell G4, that can be copied down the column to calculate the percent change for Arnold in his total compensation from March to April (the percent should be positive if his compensation has increased). \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
8. Write a formula in cell H4 that can be copied down the column to calculate Arnold’s April sales as a percentage of April’s total sales. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
9. Write a formula to calculate the number of salesman who increased their compensation from March to April. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_
10. Write a formula to calculate the total sales commission of all salesman who had sales over $5000 in April. \_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_